Henrik Norbeck's ABC Tunes

Display tune: Valse des Esquimaux

Scale: Width:

See also waltz #11

From file hnwaltz0.abc Get ABC for this tune
X:10
T:Valse des Esquimaux
T:Ookpik Waltz
R:waltz
C:Frankie Rodgers (1936-2009), British Columbia, Canada
H:Danish band La Bastringue have changed this tune around a bit. They play it
H:in a set together with waltz#11 "Nerissa", and then Marco Pollier made those
H:into one four part tune for his recording.
D:La Bastringue
D:Marco Pollier: Ebony & Brass
Z:id:hn-waltz-10
M:3/4
L:1/8
K:G
P:La Bastringue's version
DGA | B3 BcB | A2 AF ED | E G2 FGA | G2 GD (3GBd |
e2 ed ef | e2 ed BA | B d2 ^cde | d3 GBd |
e2 ed ef | e2 ed BA | B d3 BA | G E3 ED |
C2 CE FE | D F3 ED | E G2 FGA |1 G3 :|2 G3 G (3Bcd ||
|: e B3 BA | B3 BAB | d4 BA | B3 BAB |
c3 cdc | Bc BA GF | ED (3EFG FD |1 E4 (3GBd :|2 E3 ||
P:Original version
|: DEF | G3 ABd | A F3 (3DED | E G4 A | G3 ABd |
e4 ef | e d3 BA | B d3 e2 | d2 g2 f2 |
e4 ef | e d3 (3dBA | B3 d (3BAG | E4 ED |
C3 D EG | D F3 D2 | E2 G3 A |1 G3 :|2 G3 ABd ||
|: e2 B3 A | B4 e2 | d2 B3 A | B4 B2 |
A4 AB | A G3 (3GED |1 E G4 A | G2 B2 d2 :|2 E G4 E | FE D2 (3DEF :|

Previous tune | Next tune
Sheet music rendered using AbcJs